Check if a string is empty

Use this extremely useful to check whether a variable is empty or not. Originally posted at SitePointForums.

<%
'Check a variable isn't "empty"
Function IsBlank(ByRef TempVar)

    'by default, assume it's not blank
    IsBlank = False

    'now check by variable type
    Select Case VarType(TempVar)
    
        'Empty & Null
        Case 0, 1
            IsBlank = True
        
        'String
        Case 8
            If Len(TempVar) = 0 Then
                IsBlank = True
            End If
            
        'Object
        Case 9
            tmpType = TypeName(TempVar)
            If (tmpType = "Nothing") Or (tmpType = "Empty") Then
                IsBlank = True
            End If
        
        'Array
        Case 8192, 8204, 8209
            'does it have at least one element?
            If UBound(TempVar) = -1 Then
                IsBlank = True
            End If
    End Select
End Function
%>


Example Usage
<% 
If IsBlank(Session("username"))Then 
    response.redirect("LoginFail.htm") 
End If 
%>


asp is empty empty string check for empty function


Back To Top
© 1998 - 2017 psacake.com | My3C's

Version 7.2 | Advertise on this site