List Session and Application Variables

Have you ever wondered how to list all of your Session and Application variables? Both the Session and Application objects provide the Contents collection, which contains all of the session and application variables that are not objects (i.e., arrays, strings, integers, etc.).

You can loop through this collection using the For Each ... Next. Since arrays are included in the Contents collection, we need to determine if the current variable is an array, using the IsArray function. If the variable is an array, we need to loop through the array one element at a time, displaying each element. If the variable is not an array, we need to simply display the variable.

<% Option Explicit %>
 <%
    'How many session variables are there?
    Response.Write "There are " & Session.Contents.Count & _
              " Session variables<P>"
 
   Dim strName, iLoop
    'Use a For Each ... Next to loop through the entire collection
    For Each strName in Session.Contents
      'Is this session variable an array?
      If IsArray(Session(strName)) then
        'If it is an array, loop through each element one at a time
        For iLoop = LBound(Session(strName)) to UBound(Session(strName))
           Response.Write strName & "(" & iLoop & ") - " & _
                Session(strName)(iLoop) & "<BR>"
        Next
      Else
        'We aren't dealing with an array, so just display the variable
        Response.Write strName & " - " & Session.Contents(strName) & "<BR>"
      End If
    Next
 
%>

You can list the Application variables by simply changing each instance of the word Session in the code above with the word Application

asp session variables application variables list variables


Back To Top
© 1998 - 2014 psacake.com | My3C's

Version 7.0a | Advertise on this site